;**********************************************************************;
;*                 A T O M I C   D E B U G G E R                      *;
;*--------------------------------------------------------------------*;
;*    doel           : machinetaal debugger voor Atom-in-PC met       *;
;*                     ondersteuning van 6502, 65C02 en 65802         *;
;*--------------------------------------------------------------------*;
;*    filenaam       : osvbbc.inc                                     *;
;*    auteur         : Roland Leurs                                   *;
;*                     The Atomic Development Studio                  *;
;*    ontwikkeld     : maart 1998                                     *;
;*    laatste update :                                                *;
;*--------------------------------------------------------------------*;
;*    assembleren    : x6502 DEBUG                                    *;
;*--------------------------------------------------------------------*;
;*    oproep         : DEBUG                                          *;
;**********************************************************************;

osvtekst        .db 31,68,13
                .db "Esc: Quit"
                .db 31,28,15
                .db "Operating System Vectors"
                .db 31,22,22
                .db "Press space bar to exit this window."
                .db 0

statusosv       .db "Operating System Vectors",31,1,17,0

osvt            .db "nmibrkir1ir2clibytwrdwrcrdcfil"
                .db "argbgtbptgpbfndfscrpcwpc"

osv             ldx #7
                ldy #6
                jsr scrcopy
                jsr osvclear    ;wis venster
                ldx #<osvtekst
                ldy #>osvtekst
                jsr showmenu
                ldx #<statusosv
                ldy #>statusosv
                jsr statusline
                ldx #$00
                stx zp+2
osvl1           ldy #$00
osvl2           lda osvt,y
                jsr wrch
                cpx #$02
                beq osvl4
                inx
osvl3           iny
                jmp osvl2
osvl4           sty zp+3
                jsr print
                .db "vec:",9,9,$EA
                inc zp+2
                ldx zp+2
                lda $200,x
                jsr prthex
                dec zp+2
                ldx zp+2
                lda $200,x
                jsr prthex
                inc zp+2
                inc zp+2
                jsr print
                .db 9,9,9,$EA
                ldx #$00
                ldy zp+3
                cpy #$35
                beq osvl5
                jmp osvl3
osvl5           jsr rdch
                ldx #6
                ldy #7
                jsr scrcopy
                jsr osvclear            ;wis venster
                lda mem_home            ;refresh memory dump op scherm
                sta zp
                lda mem_home+1
                sta zp+1
                jsr memdump
                rts

osvclear        ldy #15                 ;wis help venster
osvclear1       ldx #1
                jsr gotoxy
                ldx #78                 ;druk 78 spaties af
                lda #' '
osvclear2       jsr wrch                ;print spatie
                dex                     ;verlaag teller
                bne osvclear2
                iny                     ;verhoog regelteller
                cpy #23                 ;laatste regel gehad?
                bne osvclear1           ;nee, dan volgende wissen
                rts                     ;einde routine