;**********************************************************************; 
;*                 A T O M I C   W I N D O W S                        *; 
;*--------------------------------------------------------------------*; 
;*    doel           : hardware afhankelijke routines                 *; 
;*--------------------------------------------------------------------*; 
;*    filenaam       : mouse.inc                                      *; 
;*    auteur         : Roland Leurs                                   *; 
;*                     The Atomic Development Studio                  *; 
;*    ontwikkeld     : oktober 1997                                   *; 
;*    laatste update : 28 januari 1998                                *; 
;*--------------------------------------------------------------------*; 
;*    wijzigingen    : v03 - DLGPOINTER voor PC werkend gemaakt       *;
;*                         - Ruimte bespaart door JSR,RTS -> JMP      *;
;*--------------------------------------------------------------------*; 
;*    assembleren    : opnemen als include file in AWxx.ASM           *; 
;*--------------------------------------------------------------------*; 
;*    oproep         : -                                              *; 
;**********************************************************************;
     
; Atom-in-PC adressen
muis_b          equ  $180
muis_x          equ  $182
muis_y          equ  $184
     
rd_mouse_button jsr setsem
                txa                     \ save registers
                pha
                tya
                pha
                ldy #muizpositie-pccomtab
                ldx #3
                jsr pccom
rdmb2           jsr leesbyte            \ lees x positie
                sta muis_x
                jsr leesbyte
                sta muis_x+1
                jsr leesbyte            \ lees y positie 
                sta muis_y
                jsr leesbyte
                sta muis_y+1
                jsr leesbyte            \ lees knoppen 
                sta muis_b              \ berg op
                jsr clrsem
                pla                     \ herstel registers
                tay
                pla
                tax
                lda muis_b              \ lees muisknoppen 
                eor #7
                rts                     \ einde routine
     
rd_x_mouse      jsr rd_mouse_button     \ lees muis info
                lda muis_x
                rts
     
rd_y_mouse      jsr rd_mouse_button     \ lees muis info
                lda muis_y
                rts
     
m_init          jsr setsem              \ test semafoor
                ldy #muizinit-pccomtab  \ init muis
                ldx #3
                jsr pccom
                jsr leesbyte            \ (dummy) lees muiscursor
                jmp mouse_on_i          \ einde routine
     
ch_mouse_cursor pha                     \ bewaar muispointer
                jsr setsem              \ test semafoor
                ldy #muizcursor-pccomtab \selecteer muiscursor
                ldx #3
                jsr pccom
                pla
                jsr zendbyte
                jmp clrsem              \ reset semafoor

mouse_on        JSR setsem              \ zet muis aan
mouse_on_i      LDY #muizaan-pccomtab
mouse_on_c      LDX #3
                JSR pccom
                JMP clrsem

mouse_off       JSR setsem              \ zet muis uit
                LDY #muizuit-pccomtab
                BNE mouse_on_c