;**********************************************************************;
;*                 A T O M I C   W I N D O W S                        *;
;*--------------------------------------------------------------------*;
;*    doel           : Interpreter en statements voor toolbox         *;
;*--------------------------------------------------------------------*;
;*    filenaam       : aw30.asm                                       *;
;*    auteur         : Kees van Oss                                   *;
;*    conversie      : Roland Leurs                                   *;
;*                     The Atomic Development Studio                  *;
;*    ontwikkeld     : juli 1997                                      *;
;*    laatste update :                                                *;
;*--------------------------------------------------------------------*;
;*    assembleren    : opnemen als includefile in AW30.ASM            *;
;*--------------------------------------------------------------------*;
;*    oproep         : -                                              *;
;**********************************************************************;



; === INTERPRETER
no_com   equ $C558

                LDX #$FF

next_com        LDY $5E
                DEY
next_chr        INX
                INY
next_vec        LDA com_tab,X
                BMI com_ok
                CMP  ($05),Y
                BEQ next_chr
int2            INX
                LDA com_tab-1,X
                BPL int2
                LDA  ($05),Y
                CMP #$2E
                BNE next_com
                INY
                DEX
                BCS next_vec
com_ok          STA $53
                LDA com_tab+1,X
                STA $52
                STY $3
                LDX #0
                STX $4
                JSR exec_com
                LDX #0
                STX $4
                JMP $C558
exec_com        JMP  ($0052)

com_tab         .db "DLGBASE"
                .db >dlgbase,<dlgbase
                .db "DLGCREATE"
                .db >dlgcreate,<dlgcreate
                .db "DLGPUSHBUTTON"
                .db >dlgpushbutton,<dlgpushbutton
                .db "DLGRADIOBUTTON"
                .db >dlgradiobutton,<dlgradiobutton
                .db "DLGCHECKBOX"
                .db >dlgcheckbox,<dlgcheckbox
                .db "DLGOPTION"
                .db >dlgoption,<dlgoption
                .db "DLGTEXT"
                .db >dlgtext,<dlgtext
                .db "DLGLABEL"
                .db >dlglabel,<dlglabel
                .db "DLGICON"
                .db >dlgicon,<dlgicon
                .db "DLGFRAME"
                .db >dlgframe,<dlgframe
                .db "DLGLIST"
                .db >dlglist,<dlglist
                .db "DLGEND"
                .db >dlgend,<dlgend
                .db >no_com,<no_com

; === INITIALISATIE SUBROUTINES
stackpointer equ $4
data      equ $C0
stack1    equ $16
stack2    equ $25
x_tmp     equ $C0
y_tmp     equ $C1
b_tmp     equ $C2
h_tmp     equ $C3
m_tmp     equ $C4
read_param   equ $C8BC
read_text    equ $CEB1
next_param   equ $C231
print_text   equ $F7D1
nulblock     equ $80
dummy_ptr_lo equ nulblock
dummy_ptr_hi equ nulblock+1
nulbl_dummy  equ nulblock+2
dlg_buffer   equ $140
dlg_base_lo  equ $16D
dlg_base_hi  equ $16E
x_base    equ $16F
y_base    equ $170
dlg_ptr_lo   equ $171
dlg_ptr_hi   equ $172
x_min     equ $173
x_max      equ  $174
y_min      equ  $175
y_max      equ  $176
store_mode    equ  $177
store_var     equ  $178
store_len     equ  $179
store_style   equ  $17A
store_x    equ  $17B
store_y    equ  $17C
store_width   equ  $17D
store_height  equ  $17E

; === LEES PARAMETERS
get             JSR read_var
                RTS
get2            JSR read_txt
                LDX #$FF
count           INX
                LDA dlg_buffer,X
                CMP #$0D
                BNE count
                STX store_len
                JSR read_num
                STA store_style
                JSR read_num
                STA store_x
                JSR read_num
                STA store_y
                RTS
get3            JSR read_num
                STA store_width
                RTS
get4            JSR read_num
                STA store_height
                RTS
get5            JSR read_num
                STA store_var
                RTS

; === COMMANDO DLGBASE ADRES
dlgbase         JSR m_init
                JSR read_num
                STA dlg_base_lo
                STA dlg_ptr_lo
                LDA stack2
                STA dlg_base_hi
                STA dlg_ptr_hi
                LDA #$F0
                STA $B000
                LDA #$00
                STA nulblock
                LDA #$80
                STA nulblock+1
                LDX #0
ver             LDY #0
hor             LDA #$AA
                STA (nulblock),Y
                TYA
                CLC
                ADC #$20
                TAY
                LDA #$55
                STA (nulblock),Y
                TYA
                SEC
                SBC #$1F
                TAY
                CPY #$20
                BNE hor
                CLC
                LDA nulblock
                ADC #$40
                STA nulblock
                BCC no_add3
                INC nulblock+1
no_add3         INX
                CPX #$60
                BNE ver
                RTS

; === COMMANDO DLGCREATE, DLGLIST, DLGDROPLIST
dlgcreate       LDA #0
                STA store_mode
                JSR param
                LDA store_x
                STA x_base
                STA x_min
                LDA store_y
                STA y_base
                STA y_min
                CLC
                LDA x_min
                ADC store_width
                STA x_max
                CLC
                LDA y_min
                ADC store_height
                STA y_max
                JSR store_dat
                LDA x_min
                STA x_tmp
                LDA y_min
                STA y_tmp
                LDA store_width
                STA b_tmp
                LDA store_height
                STA h_tmp
                JSR kader
                LDA #$FF
                STA m_tmp
                JSR block
                LDA #1
                STA store_mode
                LDA store_len
                BEQ chk_ok
                LDA #$00
                STA m_tmp
                LDA #$01
                STA h_tmp
                LDA store_style
                AND #32
                BEQ no_bigkop
                INC h_tmp
no_bigkop       JSR block
                SEC
                LDA store_width
                SBC store_len
                LSR A
                CLC
                ADC x_min
                TAX
                LDY y_min
                LDA store_len
                JSR txt
                SEC
                LDA store_width
                SBC #$05
                STA store_x
                LDY store_height
                DEY
                DEY
                STY store_y
                LDA store_style
                AND #$C0
                STA store_style
chk_ok          AND #$40
                BNE ok_knop
                SEC
                LDA store_width
                SBC #$09
                STA store_x
chk_cancel      LDA store_style
                AND #$80
                BNE cancel_knop
end             RTS
cancel_knop     LDA #"C"
                STA dlg_buffer
                LDA #"a"
                STA dlg_buffer+1
                LDA #"n"
                STA dlg_buffer+2
                LDA #"c"
                STA dlg_buffer+3
                LDA #"e"
                STA dlg_buffer+4
                LDA #"l"
                STA dlg_buffer+5
                LDA #$06
                STA store_len
                LDA #$FF
                STA store_var
                JSR pb_set
                JMP end
ok_knop         LDA #"O"
                STA dlg_buffer
                LDA #"k"
                STA dlg_buffer+1
                LDA #2
                STA store_len
                LDA #0
                STA store_var
                JSR pb_set
                SEC
                LDA store_width
                SBC #$0E
                STA store_x
                JMP chk_cancel

dlglist         LDA #9
                STA store_mode
                JSR param
                JSR store_dat
                RTS

; ===  LEES VAR,TEXT $,STYLE,X,Y,WIDTH,HEIGHT
param           JSR get
                JSR get2
                JSR get3
                JSR get4
                RTS

; === COMMANDO DLGPUSHBUTTON, DLGOPTION, DLGICON
dlgpushbutton   LDA #1
                STA store_mode
                JSR param2
pb_set          JSR limits
                INC x_max
                INC x_max
                JSR store_dat
                LDA x_min
                STA x_tmp
                LDA y_min
                STA y_tmp
                CLC
                LDA store_len
                ADC #2
                STA b_tmp
                LDA #1
                STA h_tmp
                LDA store_style
                AND #32
                BEQ pb_low
                INC h_tmp
pb_low          JSR kader
                LDA store_style
                ORA #4
                STA store_style
                LDA #" "
                LDX x_min
                LDY y_min
                JSR sprite
                LDA store_len
                INX
                JSR txt
                LDA #126
                LDX x_max
                DEX
                JSR sprite
                RTS
pb_click        LDA x_min
                STA x_tmp
                LDA y_min
                STA y_tmp
                SEC
                LDA x_max
                SBC x_min
                STA b_tmp
                SEC
                LDA y_max
                SBC y_min
                STA h_tmp
                LDA #$FE
                STA m_tmp
                JSR block
pb_wait         JSR chk_ret_key
                JSR block
pb_cont         LDA dlg_base_lo
                STA dummy_ptr_lo
                LDA dlg_base_hi
                STA dummy_ptr_hi
                LDY #5
                LDA (dummy_ptr_lo),Y
                TAX
                LDA store_var
                STA $2E1,X
                RTS

dlgoption       LDA #4
                STA store_mode
                JSR param2
                JSR limits
                JSR store_dat
                LDA store_len
                LDX x_min
                LDY y_min
                JSR txt
                RTS
op_click        JSR chk_ret_key
                JMP pb_cont

dlgicon         LDA #7
                STA store_mode
                JSR param2
                JSR limits
                LDA store_style
                AND #$38
                STA store_style
                LDA store_len
                BEQ no_text
                LDY y_min
                INY
                INY
                LDA store_style
                AND #32
                BEQ not_big4
                INY
                INY
not_big4        LDA store_len
                LSR A
                STA nulblock
                SEC
                LDA x_min
                SBC nulblock
                TAX
                INX
                LDA store_len
                JSR txt
no_text         LDY y_min
                LDA store_var
                STA dlg_buffer
                LDX x_min
                LDY y_min
                LDA #1
                JSR txt
                INC dlg_buffer
                INC dlg_buffer
                INX
                LDA #1
                JSR txt
                INY
                DEX
                DEC dlg_buffer
                LDA store_style
                AND #32
                BEQ not_big
                INY
not_big         LDA #1
                JSR txt
                INC dlg_buffer
                INC dlg_buffer
                INX
                LDA #1
                JSR txt
                RTS

; ===  LEES NR,TEXT $,STYLE,X,Y
param2          JSR get5
                JSR get2
                RTS

; === COMMANDO DLGLABEL
dlglabel        LDA #6
                STA store_mode
                JSR param3
                CLC
                LDA x_base
                ADC store_x
                TAX
                CLC
                LDA y_base
                ADC store_y
                TAY
                LDA store_len
                JSR txt
                RTS

; ===  LEES TEXT $,STYLE,X,Y
param3          JSR get2
                RTS

; === COMMANDO DLGRADIOBUTTON, DLGCHECKBOX
tmp_var    equ  $CA
bitmask    equ  $CB
r_ptr_lo   equ  $CC
r_ptr_hi   equ  $CD

dlgradiobutton  LDA #2
                STA store_mode
                JSR param4
                JSR limits
                INC x_max
                INC x_max
                JSR store_dat
                LDX x_min
                INX
                INX
                LDY y_min
                LDA store_len
                JSR txt
rb_cont         LDA #0
                STA store_style
                LDA #1
                STA bitmask
                LDA dlg_base_lo
                STA r_ptr_lo
                LDA dlg_base_hi
                STA r_ptr_hi
rb_loop         JSR inc_r_ptr
                LDA r_ptr_hi
                CMP dlg_ptr_hi
                BEQ test_lo
                JMP test_ok
test_lo         LDA r_ptr_lo
                CMP dlg_ptr_lo
                BEQ rb_end
test_ok         LDA r_ptr_lo
                STA nulbl_dummy
                LDA r_ptr_hi
                STA nulbl_dummy+1
                JSR dat_read
                LDA store_var
                STA tmp_var
                LDA store_mode
                CMP #2
                BNE rb_loop
                LDA store_var
                CMP tmp_var
                BNE rb_loop
                LDA bitmask
                LDY #11
                STA (r_ptr_lo),Y
                LDX store_var
                LDA $2E1,X
                AND bitmask
                BEQ rb_leeg
                LDA bitmask
                STA $2E1,X
                LDA #134
                JMP rb_set
rb_leeg         LDA #135
rb_set          LDX x_min
                LDY y_min
                JSR sprite
                LDA bitmask
                ASL A
                STA bitmask
                JMP rb_loop
rb_end          RTS
rb_click        JSR chk_ret_key
                LDA $90
                STA nulbl_dummy
                LDA $91
                STA nulbl_dummy+1
                JSR dat_read
                LDA store_var
                STA tmp_var
                TAX
                LDY #11
                LDA (foc_ptr_lo),Y
                STA $2E1,X
                JSR un_foc_item
                JSR rb_cont
                JSR foc_item
                RTS
inc_r_ptr       CLC
                LDA r_ptr_lo
                ADC #12
                STA r_ptr_lo
                BCC end_inc_ptr
                INC r_ptr_hi
end_inc_ptr     RTS

dlgcheckbox     LDA #3
                STA store_mode
                JSR param4
                JSR limits
                INC x_max
                INC x_max
                JSR store_dat
                LDX x_min
                INX
                INX
                LDY y_min
                LDA store_len
                JSR txt
cb_set          LDA #0
                STA store_style
                LDX store_var
                LDA $2E1,X
                BEQ cb_empty
                LDA #136
                JMP cb_put
cb_empty        LDA #137
cb_put          LDX x_min
                LDY y_min
                JSR sprite
                RTS
cb_click        JSR chk_ret_key
                LDX store_var
                LDA $2E1,X
                BEQ cb_on
                LDA #0
                STA $2E1,X
                JMP cb_set
cb_on           LDA #1
                STA $2E1,X
                JMP cb_set

; ===  LEES VAR,TEXT $,STYLE,X,Y
param4          JSR get
                JSR get2
                RTS

; === COMMANDO DLGTEXT
tx_curs_pos   equ  $CB
esc        equ  $1B
bsp        equ  $7F
ret        equ  $0D
dlgtext         LDA #5
                STA store_mode
                JSR param5
                JSR limits
                JSR store_dat
                LDX x_min
                LDY y_min
                LDA store_len
                JSR txt
                JSR tx_buf
                CLC
                LDA x_min
                ADC store_len
                ADC #1
                STA x_tmp
                LDA y_min
                STA y_tmp
                LDA store_width
                STA b_tmp
                LDA #1
                STA h_tmp
                JSR kader
                LDA #0
                STA store_style
                JSR tx_string
                RTS
tx_click        JSR chk_ret_key
                JSR read_dat
                JSR tx_buf
                LDA #0
                STA store_style
                STA tx_curs_pos
tx_loop         JSR tx_string
                JSR tx_curs_inv
                CLC
                LDA x_min
                ADC store_len
                ADC #1
                ADC tx_curs_pos
                TAX
                LDY tx_curs_pos
                LDA dlg_buffer,Y
                LDY y_min
                JSR sprite
                JSR tx_curs_inv
tx_scanloop     JSR $FE94
                CMP #esc
                BEQ tx_esc
                CMP #ret
                BEQ tx_ret
                CMP #bsp
                BEQ tx_bsp
                CMP #32
                BMI tx_scanloop
                CMP #127
                BPL tx_scanloop
                LDX tx_curs_pos
                STA dlg_buffer,X
                JSR tx_curs_verhoog
                JMP tx_loop
tx_curs_verlaag LDA tx_curs_pos
                BEQ tx_curs_end
                DEC tx_curs_pos
                RTS
tx_curs_verhoog INC tx_curs_pos
                LDA tx_curs_pos
                CMP store_width
                BNE tx_curs_end
                DEC tx_curs_pos
tx_curs_end     RTS
tx_bsp          LDA tx_curs_pos
                BEQ tx_scanloop
                JSR tx_curs_verlaag
                LDX tx_curs_pos
                LDA #32
                STA dlg_buffer,X
                JMP tx_loop
tx_ret          LDX store_var
                LDA $2E1,X
                STA dummy_ptr_lo
                LDA $2FC,X
                STA dummy_ptr_hi
                LDY #0
tx_buf_copy     LDA dlg_buffer,Y
                STA (dummy_ptr_lo),Y
                INY
                CMP #$0D
                BNE tx_buf_copy
                JSR tx_string
                JSR chk_ret_key
tx_esc          RTS

tx_buf          LDX store_var
                LDA $2E1,X
                STA dummy_ptr_lo
                LDA $2FC,X
                STA dummy_ptr_hi
                LDY #$FF
tx_copy         INY
                LDA  (dummy_ptr_lo),Y
                STA dlg_buffer,Y
                CMP #$0D
                BNE tx_copy
                STY store_width
                RTS
tx_string       CLC
                LDA x_min
                ADC store_len
                ADC #1
                TAX
                LDY y_min
                LDA store_width
                JSR txt
                RTS
tx_curs_inv     LDA store_style
                EOR #8
                STA store_style
                RTS

; ===  LEES VAR,TEXT $,STYLE,X,Y WIDTH
param5          JSR get
                JSR get2
                JSR get3
                RTS

; === COMMANDO DLGFRAME
dlgframe        LDA #8
                STA store_mode
                JSR param6
                CLC
                LDA x_base
                ADC store_x
                STA x_min
                STA x_tmp
                CLC
                LDA y_base
                ADC store_y
                STA y_min
                STA y_tmp
                LDA store_width
                STA b_tmp
                LDA store_height
                STA h_tmp
                JSR kader
                SEC
                LDA store_width
                SBC store_len
                LSR A
                CLC
                ADC x_min
                TAX
                LDY y_min
                DEY
                LDA store_len
                JSR txt
                RTS

; ===  LEES TEXT $,STYLE,X,Y WIDTH,HEIGHT
param6          JSR get2
                JSR get3
                JSR get4
                RTS

; === DLGEND

foc_ptr_lo      equ  $90
foc_ptr_hi      equ  $91
scan_toets      equ  $FE71
copy            equ  $0E
delete          equ  $0F
return          equ  $0D
escape          equ  $3B

dlgend          LDA dlg_base_lo
                STA foc_ptr_lo
                LDA dlg_base_hi
                STA foc_ptr_hi
                JSR inc_foc_ptr
                JSR foc_item
scanloop        JSR scan_toets
                BCC end_scan
                JSR scan_muis
                BCS scanloop
end_scan        CPY #copy
                BEQ copy_key
                CPY #delete
                BEQ del_key
                CPY #return
                BEQ ret_key
                CPY #escape
                BNE scanloop
                RTS
copy_key        JSR un_foc_item
                JSR inc_foc_ptr
                LDA foc_ptr_lo
                CMP dlg_ptr_lo
                BNE copy_end
                LDA foc_ptr_hi
                CMP dlg_ptr_hi
                BNE copy_end
                LDA dlg_base_lo
                STA foc_ptr_lo
                LDA dlg_base_hi
                STA foc_ptr_hi
                JSR inc_foc_ptr
copy_end        JSR foc_item
copy_wait       jsr scan_toets
                CPY #copy
                BEQ copy_wait
                JMP scanloop
del_key         JSR un_foc_item
                JSR dec_foc_ptr
                LDA foc_ptr_lo
                CMP dlg_base_lo
                BNE del_end
                LDA foc_ptr_hi
                CMP dlg_base_hi
                BNE del_end
                LDA dlg_ptr_lo
                STA foc_ptr_lo
                LDA dlg_ptr_hi
                STA foc_ptr_hi
                JSR dec_foc_ptr
del_end         JSR foc_item
del_wait        JSR scan_toets
                CPY #delete
                BEQ del_wait
                JMP scanloop
ret_key         JSR read_dat
                LDA store_mode
                CMP #1
                BNE chk_rb
                JSR un_foc_item
                JMP pb_click
chk_rb          CMP #2
                BNE chk_cb
                JSR rb_click
chk_cb          CMP #3
                BNE chk_op
                JSR cb_click
chk_op          CMP #4
                BNE chk_te
                JSR un_foc_item
                JMP op_click
chk_te          CMP #5
                BNE chk_li
                JSR tx_click
chk_li
chk_end         JMP scanloop
esc_key         TYA
                JMP scanloop
un_foc_item
foc_item        LDY #0
copy_data       LDA  (foc_ptr_lo),Y
                STA x_tmp,Y
                INY
                CPY #4
                BNE copy_data
                JSR focus
                RTS
inc_foc_ptr     CLC
                LDA foc_ptr_lo
                ADC #12
                STA foc_ptr_lo
                BCC end_sub
                INC foc_ptr_hi
dec_foc_ptr     SEC
                LDA foc_ptr_lo
                SBC #12
                STA foc_ptr_lo
                BCS end_sub
                DEC foc_ptr_hi
end_sub         RTS

; === LEES VARIABELE  (A-Z)
read_var        JSR skip_spc
                CMP #"A"
                BMI no_var
                CMP #"["
                BPL no_var
                STA store_var
                INY
                STY $3
                JSR next_param
                RTS
no_var          JSR print_text
                .db "VARIABELE ERROR"
                NOP
                BRK

; === LEES GETAL OF BEREKENING
read_num        JSR read_param
                JSR next_param
                LDA stack1
                LDY #0
                STY stackpointer
                RTS

; === LEES TEXT
read_txt        JSR read_text
                JSR next_param
                RTS

; === SKIP SPATIES
skip            INY
skip_spc        LDA ($05),Y
                CMP #" "
                BEQ skip
                RTS

; === ZET PARAMETERS IN BUFFER
reset_buf       PHA
                LDA #<dlg_buffer
                STA nulbl_dummy
                LDA #dlg_buffer/256
                STA nulbl_dummy+1
                PLA
store_byte      STA stack1
                PHA
                TXA
                PHA
                TYA
                PHA
                LDY #$0
                LDA stack1
                STA (nulbl_dummy),Y
                INC nulbl_dummy
                LDA #255
                STA (nulbl_dummy),Y
ret_store       LDY #0
                STY stackpointer
                PLA
                TAY
                PLA
                TAX
                PLA
                RTS

; === ZET PARAMETERS IN TABEL
store_dat       LDA store_style
                AND #16
                BNE no_inc
                LDA dlg_ptr_lo
                STA dummy_ptr_lo
                LDA dlg_ptr_hi
                STA dummy_ptr_hi
                LDX #$32
                LDY #$FF
volgende        INX
                INY
                LDA dlg_buffer,X
                STA (dummy_ptr_lo),Y
                CPX #$3E
                BNE volgende
                INY
                CLC
                TYA
                ADC dlg_ptr_lo
                STA dlg_ptr_lo
                BCC no_inc
                INC dlg_ptr_hi
no_inc          RTS

; === LEES PARAMETERS UIT TABEL
read_dat        LDA foc_ptr_lo
                STA nulbl_dummy
                LDA foc_ptr_hi
                STA nulbl_dummy+1
dat_read        LDX #$32
                LDY #$FF
read_nxt        INX
                INY
                LDA (nulbl_dummy),Y
                STA dlg_buffer,X
                CPX #$3E
                BNE read_nxt
                RTS

; === ZET FOCUSGRENZEN
limits          CLC
                LDA x_base
                ADC store_x
                STA x_min
                CLC
                LDA x_min
                ADC store_len
                STA x_max
                CLC
                LDA y_base
                ADC store_y
                STA y_min
                STA y_max
                INC y_max
                LDA store_style
                AND #32
                BEQ lim_end
                INC y_max
lim_end         RTS

; === CHECK OP LOSLATEN RETURN TOETS
chk_ret_key     JSR scan_toets
                CPY #return
                BEQ chk_ret_key
                RTS
; === SCAN MUIS
tmp_x           equ  $C8
tmp_y           equ  $C9

scan_muis       JSR rd_mouse_button
                AND #1
                BEQ scan_knop
no_key          SEC
                RTS
scan_knop       JSR rd_mouse_button
                AND #1
                BEQ scan_knop
                JSR rd_x_mouse
                LSR A
                LSR A
                LSR A
                STA tmp_x
                JSR rd_y_mouse
                EOR #$FF
                LSR A
                LSR A
                LSR A
                STA tmp_y
                LDA dlg_base_lo
                STA r_ptr_lo
                LDA dlg_base_hi
                STA r_ptr_hi
chk_loop        JSR inc_r_ptr
                LDA r_ptr_hi
                CMP dlg_ptr_hi
                BNE tab_read
                LDA r_ptr_lo
                CMP dlg_ptr_lo
                BEQ no_key
tab_read        LDA r_ptr_lo
                STA nulbl_dummy
                LDA r_ptr_hi
                STA nulbl_dummy+1
                JSR dat_read
                LDA tmp_x
                CMP x_min
                BMI chk_loop
                CMP x_max
                BPL chk_loop
                LDA tmp_y
                CMP y_min
                BMI chk_loop
                CMP y_max
                BPL chk_loop
                LDA r_ptr_hi
                CMP foc_ptr_hi
                BNE not_sel
                LDA r_ptr_lo
                CMP foc_ptr_lo
                BNE not_sel
                LDY #return
                CLC
                RTS
not_sel         JSR un_foc_item
                LDA r_ptr_hi
                STA foc_ptr_hi
                LDA r_ptr_lo
                STA foc_ptr_lo
                JSR foc_item
                JMP no_key